Imports System.Windows.Forms.Design
 
''' <summary>
''' ToolStripItem RadioButton
''' </summary>
<ToolStripItemDesignerAvailabilityAttribute( _
  ToolStripItemDesignerAvailability.ToolStrip _
Or ToolStripItemDesignerAvailability.MenuStrip _
Or ToolStripItemDesignerAvailability.ContextMenuStrip _
Or ToolStripItemDesignerAvailability.StatusStrip)> _
Public Class ToolStripRadioButton
    Inherits ToolStripControlHost
 
    Public Event CheckedChanged As EventHandler
 
    Public Sub New()
        MyBase.New(New RadioButton())
    End Sub
 
    Public ReadOnly Property RadioButton() As RadioButton
        Get
            Return CType(Control, RadioButton)
        End Get
    End Property
 
    Public Property Checked() As Boolean
        Get
            Return RadioButton.Checked
        End Get
        Set(ByVal value As Boolean)
            RadioButton.Checked = value
        End Set
    End Property
 
    Protected Overrides Sub OnSubscribeControlEvents(ByVal control As Control)
        MyBase.OnSubscribeControlEvents(control)
        Dim RadioButton As RadioButton = CType(control, RadioButton)
        AddHandler RadioButton.CheckedChanged, AddressOf _
          RadioButton_CheckedChanged
    End Sub
 
    Protected Overrides Sub OnUnsubscribeControlEvents(ByVal control As Control)
        MyBase.OnUnsubscribeControlEvents(control)
        Dim RadioButton As RadioButton = CType(control, RadioButton)
        RemoveHandler RadioButton.CheckedChanged, AddressOf _
          RadioButton_CheckedChanged
    End Sub
 
    Private Sub RadioButton_CheckedChanged(ByVal sender As Object, ByVal e As _
      EventArgs)
        RaiseEvent CheckedChanged(Me, e)
    End Sub
 
End Class