''' <summary>Abfrage/Zuweisung eines Listbox-Items</summary>
    ''' <param name="index">Index des Items (Abfragen/Setzen)</param>
    ''' <value>Listbox-Item</value>
    Default Public Property Item(ByVal index As Integer) As T
        Get
            Return CType(Me.Items(index), T)
        End Get
        Set(ByVal value As T)
            Me.Items(index) = value
        End Set
    End Property
 
    ''' <summary>Einfügen eines Items an der Position: Index</summary>
    ''' <param name="index">Einfüge-Index</param>
    ''' <param name="value">einzufügendes Item</param>
    Public Sub Insert(ByVal index As Integer, ByVal value As T)
        MyBase.Items.Insert(index, value)
    End Sub
 
    ''' <summary>Einfügen eines Item-Array ab der Position StartIndex</summary>
    ''' <param name="StartIndex">Listbox-Index</param>
    ''' <param name="Items">Einzufügende Items</param>
    Public Sub InsertRange(ByVal StartIndex As Integer, ByVal Items() As T)
        For i As Integer = 0 To Items.Length - 1
            Me.Insert(StartIndex, Items(i))
            StartIndex += 1
        Next i
    End Sub
 
    ''' <summary>Entfernen eines Items (ggf. kleinster Index)</summary>
    ''' <param name="value">zu entfernendes Item</param>
    ''' <returns>War das Item vorhanden?</returns>
    Public Function Remove(ByVal value As T) As Boolean
        If Not MyBase.Items.Contains(value) Then Return False
        MyBase.Items.Remove(value)
        Return True
    End Function
 
    Public Sub RemoveAt(ByVal index As Integer)
        MyBase.Items.RemoveAt(index)
    End Sub
 
    ''' <summary>Entfernen aller Items eines Wertes</summary>
    ''' <param name="value">zu entfernender Wert</param>
    ''' <returns>Anzahl der entfernten Werte</returns>
    Public Function RemoveAll(ByVal value As T) As Integer
        Dim ret As Integer = 0
        While MyBase.Items.Contains(value)
            MyBase.Items.Remove(value)
            ret += 1
        End While
        Return ret
    End Function
 
    ''' <summary>Übertragung der Items in ein deklariertes Array</summary>
    ''' <param name="Destination">Ziel-Array für Listbix-Items</param>
    ''' <param name="ArrayIndex">StartIndex im Array</param>
    Public Sub CopyTo(ByRef Destination() As T, ByVal ArrayIndex As Integer)
        For i As Integer = 0 To MyBase.Items.Count - 1
            Destination(ArrayIndex) = Me(i) : ArrayIndex += 1
        Next i
    End Sub
 
    ''' <summary>Abfragen/Setzen des aktuell ausgewählten Items</summary>
    Public Overloads Property SelectedItem() As T
        Get
            Return (CType(MyBase.SelectedItem, T))
        End Get
        Set(ByVal value As T)
            MyBase.SelectedItem = value
        End Set
    End Property
  End Class