' Process handling
    Public Delegate Sub BeendetHandler(ByVal gekillt As Boolean)
 
    Private WithEvents Prozess As Process
    Private ProzessBeendet As Boolean
    Private Sekunden As Integer
    Private Aufräumen As BeendetHandler
    Private Zeitaus As Integer
 
    Public Sub ProzessStarten(ByVal Programm As String, ByVal Parameter As _
      String, ByVal Aufräumen As BeendetHandler, ByVal TimeoutSekunden As _
      Integer)
        Me.Aufräumen = Aufräumen
        Prozess = New Process
        ProzessBeendet = False
        Dim ProzessInfo As New ProcessStartInfo(Programm, Parameter)
        ProzessInfo.CreateNoWindow = True
        ProzessInfo.WindowStyle = ProcessWindowStyle.Hidden
        ProzessInfo.UseShellExecute = False
        Prozess.StartInfo = ProzessInfo
        Prozess.EnableRaisingEvents = True
        Prozess.Start()
        Timer1.Enabled = True
        Zeitaus = TimeoutSekunden
        Sekunden = 0
    End Sub
 
    Private Sub Prozess_Exited(ByVal sender As Object, ByVal e As _
      System.EventArgs) Handles Prozess.Exited
        ProzessBeendet = True
    End Sub
 
    Private Sub Timer1_Tick(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Timer1.Tick
        If ProzessBeendet Then
            Timer1.Enabled = False
            Aufräumen(False)
        Else
            Sekunden += 1
            If Sekunden >= Zeitaus Then
                Timer1.Enabled = False
                Prozess.Kill()
                Aufräumen(True)
            End If
        End If
    End Sub

    ' Anwendung
 
    ' Notepad starten
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Button1.Click
        Button1.Enabled = False
        ProzessStarten("Notepad.exe", String.Empty, AddressOf Button1Aufräumen, _
          10)
    End Sub
 
    ' Aufgerufen wenn Notepad Prozess beendet
    Private Sub Button1Aufräumen(ByVal gekillt As Boolean)
        Button1.Enabled = True
        If gekillt Then
            MsgBox("Prozess gekillt!")
        Else
            MsgBox("Prozess beendet!")
        End If
    End Sub

________
Alle Angaben ohne Gewähr. Keine Haftung für Vorschläge, Tipps oder sonstige Hilfe, falls es schiefgeht, nur Zeit verschwendet oder man sonst nicht zufrieden ist