const dump_file_name = "history_dump.txt" 
const dump_dir = "C:\" 
 
 
with createobject("Scripting.FileSystemObject") 
  set dump = .createtextfile(dump_dir & dump_file_name,true,0) 
end with 
 
set sh = createobject("Shell.Application") 
const ssfHISTORY = 34 
set history = sh.NameSpace(ssfHISTORY) 
'first level items a grouped by date 
'(today, yesterday, last week) 
for each item in history.items 
  dump.WriteLine history.GetDetailsOf(item,-1) 
  dump.WriteBlankLines 1 
  if item.isFolder then 
    set itFol = item.GetFolder 
    for each item2 in itFol.items 
      dump.WriteLine vbtab & itFol.GetDetailsOf(item2,-1) 
      dump.WriteBlankLines 1 
      if item2.isFolder then 
        set itFol2 = item2.GetFolder 
        for each item3 in itFol2.items 
          url = itFol2.GetDetailsOf(item3,0) 
          title = itFol2.GetDetailsOf(item3,1) 
          date_vis = itFol2.GetDetailsOf(item3,2) 
          dump.WriteLine String (3,vbtab) & date_vis & " : " & title 
          dump.WriteLine String (3,vbtab) & url 
          dump.WriteBlankLines 1 
        Next 
      end if 
    Next 
    dump.WriteLine String (80,"*") 
    dump.WriteBlankLines 1 
  end if 
next 
dump.close()