Public Class AsyncServer
 
    Public Shared Server As New AsyncServer
 
    Public Class WorkItem
        Public OutMessage As String
        Public InMessage As String
        Public Caller As Form
        Public Completed As CallBack
    End Class
 
    Public Class WorkItemCompletedEventArgs
        Inherits System.EventArgs
        Public wi As WorkItem
        Public Sub New(ByVal wi As WorkItem)
            Me.wi = wi
        End Sub
    End Class
 
    Public Delegate Sub CallBack(ByVal sender As Object, ByVal e As _
      WorkItemCompletedEventArgs)
 
    Private _closeDown As Boolean
    Private _workQueue As New Queue(Of WorkItem)
    Private _workEvent As New Threading.AutoResetEvent(False)
    Private _received As New Threading.AutoResetEvent(False)
    Private _thread As New Threading.Thread(AddressOf run)
 
    Private Function getWorkItem() As WorkItem
        Dim nextWi As WorkItem = Nothing
        Do
            SyncLock _workQueue
                If _workQueue.Count > 0 Then
                    nextWi = _workQueue.Dequeue()
                End If
            End SyncLock
            If nextWi Is Nothing Then
                _workEvent.WaitOne()
            End If
            Threading.Thread.MemoryBarrier()
        Loop While nextWi Is Nothing And Not _closeDown
        Return nextWi
    End Function 'getWorkItem() 
 
    Public Sub PostWorkItem(ByVal wi As WorkItem)
        SyncLock _workQueue
            _workQueue.Enqueue(wi)
            If _workQueue.Count = 1 Then
                ' Post (maybe) waiting work thread 
                _workEvent.Set()
            End If
        End SyncLock
    End Sub 'PostWorkItem()
 
    Public Sub Close()
        _closeDown = True
        Threading.Thread.MemoryBarrier()
        _workEvent.Set()
        _received.Set()
        Threading.Thread.Sleep(100) ' or _thread.Join([n])
    End Sub
 
    Private Sub New()
        _thread.IsBackground = True
        _thread.Start()
    End Sub
 
    Private _wi As WorkItem
 
    Private Sub run()
        _wi = getWorkItem()
        While _wi IsNot Nothing
 
            ' "Nachricht schicken"
            _timer.Enabled = True
 
            ' Warte auf "Antwort"
            _received.WaitOne()
 
            ' weiter
            _wi = getWorkItem()
        End While
    End Sub
 
    ' Ersatz für COM Port
    Private WithEvents _timer As New System.Timers.Timer(2000)
 
    Private Sub _timer_Elapsed(ByVal sender As Object, ByVal e As _
      System.Timers.ElapsedEventArgs) Handles _timer.Elapsed
        _timer.Enabled = False
 
        ' "Empfangene Nachricht setzen"
        _wi.InMessage = _wi.OutMessage & " received: " & DateTime.Now.ToString( _
          "HH:mm:ss")
 
        ' Form benachrichtigen
        _wi.Caller.Invoke(_wi.Completed, New Object() {Me, New _
          WorkItemCompletedEventArgs(_wi)})
 
        ' Sags dem Mainthread
        _received.Set()
    End Sub
 
End Class

Public Class Form1
 
    Private Sub Send_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) Handles Send.Click
        Dim wi As New AsyncServer.WorkItem
 
        wi.OutMessage = TextOut.Text & " sent: " & DateTime.Now.ToString( _
          "HH:mm:ss")
        wi.Completed = AddressOf Me.Received
        wi.Caller = Me
        AsyncServer.Server.PostWorkItem(wi)
 
    End Sub
 
    Public Sub Received(ByVal sender As Object, ByVal e As _
      AsyncServer.WorkItemCompletedEventArgs)
        TextIn.Text = e.wi.InMessage
    End Sub
 
    Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As _
      System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
        AsyncServer.Server.Close()
    End Sub
End Class

Those people who think they know everything are a great annoyance to those of us who do - Isaac Asimov